تبدیل عدد به حروف در اکسل برای مبلغ چک و فاکتور

Function AdadBeHorouf(ByVal n As Variant) As String
    Dim yekan, dah, dahgan, sadgan, vahed
    Dim s As String, part As String, i As Integer, g As Integer, groups As Integer
    yekan = Array("", "یک", "دو", "سه", "چهار", "پنج", "شش", "هفت", "هشت", "نه")
    dah = Array("ده", "یازده", "دوازده", "سیزده", "چهارده", "پانزده", "شانزده", "هفده", "هجده", "نوزده")
    dahgan = Array("", "", "بیست", "سی", "چهل", "پنجاه", "شصت", "هفتاد", "هشتاد", "نود")
    sadgan = Array("", "یکصد", "دویست", "سیصد", "چهارصد", "پانصد", "ششصد", "هفتصد", "هشتصد", "نهصد")
    vahed = Array("", " هزار", " میلیون", " میلیارد", " تریلیون")

    s = Format(Fix(Abs(n)), "0")
    If s = "0" Then AdadBeHorouf = "صفر": Exit Function
    Do While Len(s) Mod 3 <> 0: s = "0" & s: Loop
    groups = Len(s) \ 3
    If groups > 5 Then AdadBeHorouf = "عدد بیش از حد بزرگ است": Exit Function

    For i = 1 To groups
        g = CInt(Mid(s, (i - 1) * 3 + 1, 3))
        If g > 0 Then
            part = SeRaqam(g, yekan, dah, dahgan, sadgan) & vahed(groups - i)
            AdadBeHorouf = VaJoin(AdadBeHorouf, part)
        End If
    Next i
End Function

Private Function SeRaqam(ByVal g As Integer, yekan, dah, dahgan, sadgan) As String
    Dim r As Integer, t As String
    If g \ 100 > 0 Then t = sadgan(g \ 100)
    r = g Mod 100
    If r >= 10 And r < 20 Then
        t = VaJoin(t, dah(r - 10))
    Else
        If r \ 10 > 0 Then t = VaJoin(t, dahgan(r \ 10))
        If r Mod 10 > 0 Then t = VaJoin(t, yekan(r Mod 10))
    End If
    SeRaqam = t
End Function

Private Function VaJoin(ByVal a As String, ByVal b As String) As String
    If a = "" Then VaJoin = b Else VaJoin = a & " و " & b
End Function